Ⅰ. 프로세서의 제조사와 IA-32e 지원 여부 검사

• CPUID 명령어를 이용하여, 프로세서 제조사를 확인하는 방법과 IA-32e 모드를 지원하는지 확인하는 방법에 대해 살펴본다.

1. CPUID를 사용하여, 프로세서 정보 확인 방법

• CPUID는 EAX 레지스터에 설정된 값에 따라 해당 정보를 조회하며, 범용 레지스터 EAX, EBX, ECX, EDX를 통해 결과를 넘겨준다.
• CPUID 명령어 실행했을 때, 반환되는 정보는 프로세서가 생산된 제조자(인텔, AMD 등)에 따르지만, 여러 프로세서 간의 호환을 위해 공통적인 필드를 가지고 있다.
  • EAX 값 0x00000000 일 경우, 기본 CPUID 정보를 조회한다.
  • EAX 값 0x80000001 일 경우, 확장 기능 CPUID 정보를 조회한다.

2. 프로세서 제조사와 IA-32e 모드 지원 여부 확인

• 스택에 들어있는 2번째 파라미터부터 5번째 파라미터까지는 ESI 레지스터에 값을 옮긴 후, 다시 ESI 레지스터가 가리키는 어드레스에 값을 저장한다.

  • 이는 kReadCPUID( )의 파라미터가 변수의 포인터이기 때문이다.
  • 따라서, 스택에 있는 값은 실제 변수의 어드레스가 되므로 ESI 레지스터에 어드레스를 옮긴 후, 다시 ESI 레지스터가 가리키는 어드레스에 값을 저장하는 것이다.

  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ; kReadCPUID( ) 함수의 어셈블리어 코드 
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  
  ; C언어에서 호출할 수 있도록, 이름을 노출 (Export)
  global kReadCPUID
  
  SECTION .text 
  
  ; CPUID를 반환
  ;   PARAM: DWORD dwEAX, DWORD* pdwEAX, * pdwEBX, * pdwECX, * pdwEDX
  kReadCPUID:
      push ebp        ; 베이스 포인터 레지스터(EBP)를 스택에 삽입
      mov ebp, esp    ; 베이스 포인터 레지스터(EBP)에 스택 포인터 레지스터(ESP)의 값을 설정
      push eax        ; 함수에서 임시로 사용하는 레지스터로 함수의 마지막 부분에서
      push ebx        ; 스택에 삽입된 값을 꺼내 원래 값으로 복원
      push ecx    
      push edx 
      push esi 
  
      ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
      ;   EAX 레지스터의 값으로 CPUID 명령어 실행
      ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
      mov eax, dword [ebp + 8]    ; 파라미터 1(dwEAX)를 EAX 레지스터에 저장
      CPUID                       ; CPUID 명령어 실행
  
      ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
      ;   반환된 값을 파라미터에 저장
      ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
      ; *pdwEAX
      mov esi, dword [ebp + 12]   ; 파라미터 2(pdwEAX)를 ESI 레지스터에 저장
      mov dword [esi], eax        ; pdwEAX가 포인터이므로, 포인터가 가리키는 어드레스에
                                  ; EAX 레지스터의 값을 저장
  
      ; *pdwEBX
      mov esi, dword [ebp + 16]   ; 파라미터 3(pdwEBX)를 ESI 레지스터에 저장
      mov dword [ esi ], ebx      ; pdwEBX가 포인터이므로 포인터가 가리키는 어드레스에
                                  ; EBX 레지스터의 값을 저장
  
      ; *pdwECX
      mov esi, dword [ ebp + 20 ] ; 파라미터 4(pdwECX)를 ESI 레지스터에 저장
      mov dword [ esi ], ecx      ; pdwECX가 포인터이므로 포인터가 가리키는 어드레스에
                                  ; ECX 레지스터의 값을 저장
                                  
      ; *pdwEDX
      mov esi, dword [ ebp + 24 ] ; 파라미터 5(pdwEDX)를 ESI 레지스터에 저장
      mov dword [ esi ], edx      ; pdwEDX가 포인터이므로 포인터가 가리키는 어드레스에
                                  ; EDX 레지스터의 값을 저장
  
      pop esi     ; 함수에서 사용이 끝난 ESI 레지스터부터 EBP 레지스터까지를 스택에
      pop edx     ; 삽입된 값을 이용해서 복원
      pop ecx     ; 스택은 가장 마지막에 들어간 데이터가 가장 먼저 나오는
      pop ebx     ; 자료구조(Last-In, First-Out)이므로 삽입(push)의 역순으로
      pop eax     ; 제거(pop) 해야 함
      pop ebp     ; 베이스 포인터 레지스터(EBP) 복원
      ret         ; 함수를 호출한 다음 코드의 위치로 복귀
  

  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ; kReadCPUID( ) 함수의 선언
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  
  void kReadCPUID( DWORD dwEAX, DWORD* pdwEAX, DWORD* pdwEBX, DWORD* pdwECX, DWORD* pdwEDX );
  

• kReadCPUID( ) 함수를 사용하여, 제조사 문자열을 조합하는 코드

  DWORD dwEAX, dwEBX, dwECX, dwEDX;
  char vcVendorString[13] = {0, };
  
  // 프로세서 제조사 정보 읽기
  kReadCPUID (0x00, &dwEAX, &dwEBX, &dwECX, &dwEDX);
  *(DWORD*) vcVemdprString = dwEBX;
  *((DWORD*) vcVemdprString + 1) = dwEDX;
  *((DWORD*) vcVemdprString + 2) = dwECX;
  
  // 제조사 문자열이 출력됨
  kPrintString(0, 0, vcVendorString);
  

• kReadCPUID( )함수로, IA-32e 모드 지원 여부를 검사하는 코드

  • EAX 레지스터에 0x80000001를 넣은 후, CPUID 명령어를 호출하면 EDX 레지스터의 비트 29의 값으로 판단할 수 있다.

  DWORD dwEAX, dwEBX, dwECX, dwEDX;
  
  // 64비트 지원 여부 확인
  kReadCPUID (0x80000001, &dwEAX, &dwEBX, &dwECX, &dwEDX);
  
  if(dwEDX & (1 << 29)){
  		kPrintString(0, 0, "Pass");
  }
  else{
  		kPrintString(0, 0, "Fail");
  }
  

Ⅱ. IA-32e 모드용 세그먼트 디스크립터 추가

1. 보호 모드 커널 엔트리 포인트에 디스크립터 추가

• IA-32e 모드의 서브 모드 중, 64bit 모드를 사용할 것이므로 보호 모드용 세그먼트 디스크립터를 기반으로 L비트를 1로 D비트를 0으로 설정하면 된다.

  • D비트를 0으로 설정하는 이유는 L비트와 D비트가 모두 1인 경우를 다른 목적으로 예약해두었기 때문이다.

    (실제 PC의 경우, L비트와 D비트를 모두 1로 설정하면 리부팅할 수 있으니 주의해야한다.)

• IA-32e 모드 커널용 코드와 데이터 세그먼트 디스크립터 코드

  • IA-32e 모드 전환 후, 보호 모드용 세그먼트 디스크립터를 사용하지 않으므로 IA-32e 모드용 세그먼트 디스크립터를 앞쪽으로 배치하였다.

  ; GDT 테이블 정의
  GDT:
      ; 널(NULL) 디스크립터, 반드시 0으로 초기화해야 함
      NULLDescriptor:
          dw 0x0000
          dw 0x0000
          db 0x00
          db 0x00
          db 0x00
          db 0x00
  
      ; IA-32e 모드 커널용 코드 세그먼트 디스크립터
      IA_32eCODEDESCRIPTOR:     
          dw 0xFFFF       ; Limit [15:0]
          dw 0x0000       ; Base [15:0]
          db 0x00         ; Base [23:16]
          db 0x9A         ; P=1, DPL=0, Code Segment, Execute/Read
          db 0xAF         ; G=1, D=0, L=1, Limit[19:16]
          db 0x00         ; Base [31:24]  
          
      ; IA-32e 모드 커널용 데이터 세그먼트 디스크립터
      IA_32eDATADESCRIPTOR:
          dw 0xFFFF       ; Limit [15:0]
          dw 0x0000       ; Base [15:0]
          db 0x00         ; Base [23:16]
          db 0x92         ; P=1, DPL=0, Data Segment, Read/Write
          db 0xAF         ; G=1, D=0, L=1, Limit[19:16]
          db 0x00         ; Base [31:24]
          
      ; 보호 모드 커널용 코드 세그먼트 디스크립터
      CODEDESCRIPTOR:     
          dw 0xFFFF       ; Limit [15:0]
          dw 0x0000       ; Base [15:0]
          db 0x00         ; Base [23:16]
          db 0x9A         ; P=1, DPL=0, Code Segment, Execute/Read
          db 0xCF         ; G=1, D=1, L=0, Limit[19:16]
          db 0x00         ; Base [31:24]  
          
      ; 보호 모드 커널용 데이터 세그먼트 디스크립터
      DATADESCRIPTOR:
          dw 0xFFFF       ; Limit [15:0]
          dw 0x0000       ; Base [15:0]
          db 0x00         ; Base [23:16]
          db 0x92         ; P=1, DPL=0, Data Segment, Read/Write
          db 0xCF         ; G=1, D=1, L=0, Limit[19:16]
          db 0x00         ; Base [31:24]
  GDTEND:
  

• 세그먼트 디스크립터 오프셋 변경

  • IA-32e 모드용 세그먼트 디스크립터가 보호 보드용 세그먼트 디스크립터 앞에 있으므로 보호 모드로 전환할 때, 세그먼트 셀렉터의 값을 변경해줘야 한다.
  • IA-32e 모드용 코드와 데이터 디스크립터는 0x18, 0x20 이다.
  • 해당 코드는 (1.Kernel32/Source/EntryPoint.s)에서 세그먼트 디스크립터를 참조한 코드를 찾아 수정한다.

  [ORG 0x00]          ; 코드의 시작 어드레스를 0x00으로 설정
  [BITS 16]           ; 이하의 코드는 16비트 코드로 설정
  
  SECTION .text       ; text 섹션(세그먼트)을 정의
  
  START:
  		``` 생략 ```
  		; 커널 코드 세그먼트를 0x00을 기준으로 하는 것으로 교체하고 EIP의 값을 0x00을 기준으로 재설정
      ; CS 세그먼트 셀렉터 : EIP
      jmp dword 0x18: ( PROTECTEDMODE - $$ + 0x10000 )
  
  [BITS 32]               ; 이하의 코드는 32비트 코드로 설정
  PROTECTEDMODE:
      mov ax, 0x20        ; 보호 모드 커널용 데이터 세그먼트 디스크립터를 AX 레지스터에 저장
      mov ds, ax          ; DS 세그먼트 셀렉터에 설정
      mov es, ax          ; ES 세그먼트 셀렉터에 설정
      mov fs, ax          ; FS 세그먼트 셀렉터에 설정
      mov gs, ax          ; GS 세그먼트 셀렉터에 설정
  			
  		``` 생략 ```
  
  		jmp dword 0x18: 0x10200 ; C 언어 커널이 존재하는 0x10200 어드레스로 이동하여 C 언어 커널 수행Ⅲ
  

Ⅲ. IA-32e 모드 전환과 1차 정리

1. 물리 메모리 확장 기능 활성화와 페이지 테이블 설정

• 물리 메모리 확장 기능은 ‘CR4 레지스터의 PAE 비트(비트5)’가 담당하고 있으며, PAE 비트를 1로 설정해서 물리 메모리 확장 기능을 사용할 수 있었다.
• 프로세서에 페이지 테이블을 설정하려면, CR3 레지스터에 PML4 테이블의 어드레스를 저장하면 된다.
• 아래는 CR3, CR4 레지스터를 조작하여, 페이지 테이블을 설정하고 물리 메모리 확장 기능을 활성화하는 코드이다.

; CR4 컨트롤 레지스터의 PAE 비트를 1로 설정
mov eax, cr4    ; CR4 컨트롤 레지스터의 값을 EAX 레지스터에 저장
or eax, 0x20    ; PAE 비트(비트5)를 1로 설정
mov cr4, eax    ; PAE 비트가 1로 설정된 값을 CR4 컨트롤 레지스터에 저장

; CR3 컨트롤 레지스터에 PML4 테이블의 어드레스 및 캐시 활성화
mov eax, 0x100000   ; EAX 레지스터에 PML4 테이블이 존재하는 0x1000000(1MB)를 저장
mov cr3, eax        ; CR3 컨트롤 레지스터에 0x100000(1MB)를 저장